Tartalom
Index 🔎︎

# Szövegfüggvények

This section contains descriptions of the Text functions.

Ennek a parancsnak az eléréséhez...

Válassza a Beszúrás - Függvény - Kategória: Szöveg lehetőséget.

## Using double quotation marks in formulas

To include a text string in a formula, place the text string between two double quotation marks (") and Calc takes the characters in the string without attempting to interpret them. For example, the formula ="Hello world!" displays the text string Hello world! in the cell, with no surrounding double quotation marks.

The more complex formula =CONCATENATE("Life is really simple, "; "but we insist on making it complicated "; "(Confucius).") concatenates three individual strings in double quotation marks, outputting Life is really simple, but we insist on making it complicated (Confucius).

To place a literal double quotation mark within a string inside a formula, two methods can be used:

1. You can "escape" the double quotation mark with an additional double quotation mark, and Calc treats the escaped double quotation mark as a literal value. For example, the formula ="My name is ""John Doe""." outputs the string My name is "John Doe". Another simple example is the formula =UNICODE("""") which returns 34, the decimal value of the Unicode quotation mark character (U+0022) — here the first and fourth double quotation marks indicate the beginning and end of the string, while the second double quotation mark escapes the third.

2. You can use the CHAR function or the UNICHAR function to insert a double quotation mark. For example, the formula =UNICHAR(34) & "The Catcher in the Rye" & UNICHAR(34) & " is a famous book by J. D. Salinger." displays the string "The Catcher in the Rye" is a famous book by J. D. Salinger.

Ne feledje, hogy a Calc automatikus javítás funkciója módosíthatja a dupla idézőjeleket. Az automatikus javítás funkció nem módosíthatja a képletcellákon belüli idézőjeleket, de a szöveget tartalmazó, nem képletcellákban használt idézőjeleket módosíthatja. Ha például másol egy olyan karakterláncot, amelyet más tipográfiai dupla idézőjelek vesznek körül, például a bal oldali dupla idézőjel (U+201C) és a jobb oldali dupla idézőjel (U+201D), majd beilleszti egy képletcellába, hiba léphet fel. Nyissa meg az Eszközök - Automatikus javítás beállításai - Nyelvfüggő beállítások párbeszédablak Dupla idézőjelek területét a kezdő és vég tipográfiai dupla idézőjelek automatikus javításához használt karakterek beállításához. A funkció kikapcsolásához vegye ki a jelölést a Csere gombból.

## ARABIC

Returns the numeric value corresponding to a Roman number expressed as text.

## ASC

Converts double-byte (full-width) characters to single-byte (half-width) ASCII and katakana characters.

## JIS

Converts single-byte (half-width) ASCII or katakana characters to double-byte (full-width) characters.

## REGEX

Matches and extracts or optionally replaces text using regular expressions.

## ROMAN

Converts a number into a Roman numeral. The value range must be between 0 and 3999. A simplification mode can be specified in the range from 0 to 4.

## VALUE

Converts the string representation of a number to numeric form. If the supplied string is a valid date, time, or date-time, the corresponding date-time serial number is returned.

### WEBSZOLGÁLTATÁS

Webes tartalom lekérése egy URI-ról.

### XMLSZŰRÉS

Egy XPath-kifejezést alkalmaz egy XML-dokumentumra.

### URL.KÓDOL

Returns a URL-encoded string.

## ALAP

Converts a positive integer to a specified base into a text from the numbering system. The digits 0-9 and the letters A-Z are used.

#### Szintaxis

ALAP(szám; számrendszer [; minimális_hossz])

A szám a konvertálandó pozitív egész szám.

Radix indicates the base of the numeral system. It may be any positive integer between 2 and 36.

A minimális_hossz (opcionális) meghatározza a létrehozott karaktersorozat minimális hosszát. Ha a szöveg rövidebb a jelzett minimális hossznál, akkor a karakterlánc bal oldalához a függvény nullákat ad.

#### Példa

Az =ALAP(17;10;4) függvény a 0017 értéket adja vissza a tízes számrendszerben.

Az =ALAP(17;2) függvény az 10001 értéket adja vissza kettes számrendszerben.

Az =ALAP(255;16;4) függvény a 00FF értéket adja vissza hexadecimális számrendszerben.

#### Lásd még

TIZEDES

## AZONOS

Összehasonlít két szöveges karakterláncot. Ha azok megegyeznek, IGAZ értéket ad vissza. Ez a függvény különbséget tesz kis- és nagybetűk között.

#### Szintaxis

AZONOS("szöveg_1"; "szöveg_2")

A szöveg_1 az első összehasonlítandó szöveg.

A szöveg_2 a második összehasonlítandó szöveg.

#### Példa

Az =AZONOS("microsystems";"Microsystems") függvény HAMIS értéket ad vissza.

## BAHTSZÖVEG

Átvált egy számot thai nyelvű, a thai pénznem nevét is tartalmazó szöveggé.

#### Szintaxis

BAHTSZÖVEG(szám)

A szám bármilyen szám lehet. A szám egész része után a „baht” szöveget, a tizedes tört része után a „satang” szöveget illeszti a függvény.

#### Példa

A =BAHTSZÖVEG(12,65) thai karakterekkel írva a következő jelentésű szöveget adja vissza: „tizenkét baht hatvanöt satang”.

#### Technikai információk

This function is not part of the Open Document Format for Office Applications (OpenDocument) Version 1.3. Part 4: Recalculated Formula (OpenFormula) Format standard. The name space is

COM.MICROSOFT.BAHTTEXT

## BAL

Egy szöveg első (néhány) karakterét adja vissza.

#### Szintaxis

BAL("szöveg" [; szám])

A szöveg, amelyben a kezdő karakterek keresendők.

A szám (opcionális) a kezdő szövegből kiválasztásra kerülő karakterek száma. Ha a paraméter nincs megadva, akkor egy karakter kerül visszaadásra.

#### Példa

A =BAL("kimenet";2) eredménye „ki”.

## BAL2

Egy kétbájtos karakterkészlettel írt szöveg első (néhány) karakterét adja vissza.

Ez a funkció a LibreOffice 4.2 óta érhető el.

#### Szintaxis

BAL2("szöveg" [; bájtok_száma])

A szöveg, amelyben a kezdő karakterek keresendők.

A bájtok_száma (opcionális) a szövegből kiválasztásra kerülő karakterek száma. Ha a paraméter nincs megadva, akkor egy karakter kerül visszaadásra.

#### Példa

=LEFTB("中国";1) returns " " (1 byte is only half a DBCS character and a space character is returned instead).

=LEFTB("中国";2) returns "中" (2 bytes constitute one complete DBCS character).

=LEFTB("中国";3) returns "中 " (3 bytes constitute one DBCS character and a half; the last character returned is therefore a space character).

=LEFTB("中国";4) returns "中国" (4 bytes constitute two complete DBCS characters).

=LEFTB("office";3) returns "off" (3 non-DBCS characters each consisting of 1 byte).

## CSERE

Kicseréli egy karakterlánc részét egy másik karakterláncra. A függvény használható mind karakterek, mind pedig számok cseréjére (az utóbbi esetben a számok automatikusan szöveggé konvertálódnak). A függvény eredménye mindig szövegformátumban kerül megjelenítésre. Ha további számításokat kíván végezni a szövegre cserélt számmal, akkor azt vissza kell konvertálnia szám formátumba az ÉRTÉK függvény segítségével.

Minden számot tartalmazó szöveget idézőjelek közé kell tenni, ha nem szeretné azt számként értelmezni, és automatikusan szöveggé alakítani.

#### Szintaxis

CSERE("szöveg"; pozíció; hossz; "új_szöveg")

A szöveg az a szöveg, amelynek egy része lecserélésre kerül.

A pozíció a szövegen belüli pozíció, amely a csere kezdőpontját jelöli.

A hossz a szövegen belül lecserélendő karakterek száma.

Az új_szöveg a szöveget felváltó új szöveg.

#### Példa

A =CSERE("1234567";1;1;"444") eredményül „444234567” értéket ad. Az 1. pozíción található egy karakter a teljes új_szövegre módosul

## FIX

Returns a number as text with a specified number of decimal places and optional thousands separators.

#### Szintaxis

FIXED(Number; [Decimals = 2 [; NoThousandsSeparators = FALSE]])

Number is rounded to Decimals places (after the decimal separator) and the result formatted as text, using locale-specific settings.

Decimals (optional) refers to the number of decimal places to be displayed. If Decimals is negative, Number is rounded to ABS(Decimals) places to the left from the decimal point. If Decimals is a fraction, it is truncated actually ignoring what is the closest integer.

NoThousandsSeparators (optional) determines whether the thousands separator is used. If it is TRUE or non-zero, then group separators are omitted from the resulting string. If the parameter is equal to 0 or if it is missing altogether, the thousands separators of your current locale setting are displayed.

#### Példa

A =FIX(1234567,89;3) eredményül az 1 234 567,890 karakterláncot adja.

=FIXED(123456.789;;TRUE) returns 123456.79 as a text string.

=FIXED(12345.6789;-2) returns 12,300 as a text string.

=FIXED(12134567.89;-3;1) returns 12135000 as a text string.

=FIXED(12345.789;3/4) returns 12,346 as a text string.

=FIXED(12345.789;8/5) returns 12,345.8 as a text string.

## FORINT

Converts a number to a string representing the amount in the currency format, rounded to a specified decimal places, using the decimal separator that corresponds to the current locale setting. In the Value field enter the number to be converted. Optionally, you may enter the number of decimal places in the Decimals field. If no value is specified, all numbers in currency format will be displayed with two decimal places.

A pénznem beállítást a rendszerbeállításoknál adhatja meg.

#### Szintaxis

FORINT(érték [; tizedesjegyek])

Az érték lehet szám, számot tartalmazó cellára mutató hivatkozás vagy számot eredményező képlet.

A tizedesjegyek (opcionális) a tizedesjegyek száma.

#### Példa

=DOLLAR(255) returns $255.00 for the English (USA) locale and USD (dollar) currency; ￥255.00 for the Japanese locale and JPY (yen) currency; or 255,00 € for the German (Germany) locale and EUR (euro) currency.

A =FORINT(367.456;2) függvény a 367,46 Ft értéket adja vissza.

## HELYETTE

Régi szöveg újra kicserélése egy karakterláncban.

#### Szintaxis

SUBSTITUTE("Text"; "SearchText"; "NewText" [; Occurrence])

A szöveg a kicserélni kívánt szövegszegmenseket tartalmazó szöveg.

A keresendő_szöveg (a meghatározott számú alkalommal) kicserélésre kerülő szöveg.

Az új_szöveg a régi szövegszegmenst felváltó szöveg.

Az előfordulás (opcionális) meghatározza, hogy a keresett szöveg melyik előfordulása legyen lecserélve. Ha a paraméter nincs megadva, akkor a keresett szöveg valamennyi előfordulása le lesz cserélve.

#### Példa

A =HELYETTE("123123123";"3";"abc") eredménye 12abc12abc12abc.

A =HELYETTE("123123123";"3";"abc";2) eredménye 12312abc123.

## HOSSZ

Egy szövegnek a szóközökkel együtt vett hosszát adja eredményül.

#### Szintaxis

HOSSZ("szöveg")

A szöveg az a szöveg, amelynek hosszát meg kívánja határozni.

#### Példa

A =HOSSZ("Jó napot") eredménye 8.

A =HOSSZ(12345,67) eredménye 8.

## HOSSZ2

A kétbájtos karakterkészletet használó nyelvek esetén a szöveg leírásához szükséges bájtok számát adja vissza.

Ez a funkció a LibreOffice 4.2 óta érhető el.

#### Szintaxis

HOSSZ2("szöveg")

A szöveg az a szöveg, amelynek hosszát meg kívánja határozni.

#### Példa

A =HOSSZ2("中") eredménye 2 (1 kétbájtos karakterkészletbeli karakter két bájtból áll).

A =HOSSZ2("中国") eredménye 4 (2 kétbájtos karakterkészletbeli karakter, egyenként 2 bájt).

A =HOSSZ2("iroda") eredménye 6 (6 nem kétbájtos karakterkészletbeli karakter, egyenként egy bájt).

A =HOSSZ2("空手道") eredménye 6.

A =HOSSZ2(12345,67) eredménye 8.

## JOBB

Egy szöveg utolsó (néhány) karakterét adja vissza.

#### Szintaxis

JOBB("szöveg" [; szám])

A szöveg a szöveg, amelynek jobb oldali részét meg kívánja határozni.

Number (optional) is the number of characters from the right part of the text. If this parameter is not defined, one character is returned.

#### Példa

A =JOBB("Sun";2) eredménye un.

## JOBB2

Egy kétbájtos karakterkészlettel írt szöveg utolsó (néhány) karakterét adja vissza.

Ez a funkció a LibreOffice 4.2 óta érhető el.

#### Szintaxis

JOBB2("szöveg" [; bájtok_száma])

A szöveg a szöveg, amelynek jobb oldali részét meg kívánja határozni.

Number_bytes (optional) specifies the number of characters you want RIGHTB to extract, based on bytes. If this parameter is not defined, one byte is returned.

#### Példa

A =JOBB2("中国";1) eredménye " " (1 bájt csak fele egy kétbájtos karakterkészletbeli karakternek, ehelyett egy szóköz kerül visszaadásra).

A =JOBB2("中国";2) eredménye "国" (2 bájt egy kétbájtos karakterkészletbeli karaktert alkot).

A =JOBB2("中国";3) eredménye " 国" (3 bájt egy fél és egy egész kétbájtos karakterkészletbeli karaktert alkot, az első fél helyett egy szóköz kerül visszaadásra).

A =JOBB2("中国";4) eredménye "中国" (4 bájt két teljes kétbájtos karakterkészletbeli karaktert alkot).

A =JOBB2("iroda;3") eredménye "oda" (3 nem kétbájtos karakterkészletbeli karakter, egyenként egy bájt).

## KARAKTER

Egy számot karakterré alakít át, az aktuális kódtábla szerint. A szám egy, két vagy három számjegyű egész szám lehet.

A 127-nél nagyobb kódok a rendszer karaktertáblázatától függenek (például ISO-8859-1, ISO-8859-2, Windows-1252, Windows-1250), és ezért nem biztos, hogy átvihetők.

#### Szintaxis

KARAKTER(szám)

A szám 1 és 255 közötti szám, amely a karakter kódértékét jelöli.

#### Példa

A =KARAKTER(100) a d karaktert adja eredményül.

Az ="abc" & KARAKTER(10) & "def" egy újsor karaktert szúr be a karakterláncba.

## KIMETSZ

Eltávolítja a szóközöket egy karakterláncból, a szavak között csak egy szóköz marad.

#### Szintaxis

KIMETSZ("szöveg")

A szöveg az a szöveg, amelyből a szóközök eltávolításra kerülnek.

#### Példa

=TRIM(" hello world ") returns hello world without leading and trailing spaces and with single space between words.

## KISBETŰ

Egy szövegrész minden nagybetűjét kisbetűre cseréli.

#### Szintaxis

KISBETŰ("szöveg")

A szöveg a konvertálandó szöveg.

#### Példa

A =KISBETŰ("Sun") függvény a „sun” értéket adja vissza.

## KÓD

Egy szöveg első karakterének numerikus kódját adja eredményül.

#### Szintaxis

KÓD("szöveg")

A szöveg az a szöveg, amelyre vonatkozóan az első karakter kódját meg kívánja állapítani.

A 127-nél nagyobb kódok a rendszer karaktertáblázatától függenek (például ISO-8859-1, ISO-8859-2, Windows-1252, Windows-1250), és ezért nem biztos, hogy átvihetők.

#### Példa

A =KÓD("Hieronymus") eredményül 72-t, a =CODE("hieroglifa") pedig 104-et ad.

Az itt használt kódok nem az ASCII-kódokra hivatkoznak, hanem az aktuálisan betöltött kódtáblázatra.

## KÖZÉP

Eredményül egy karakterlánc egy darabját adja vissza. A kezdőpozíciót, illetve a karakterek számát a paraméterek határozzák meg.

#### Szintaxis

KÖZÉP("szöveg"; kezdés; szám)

A szöveg olyan szöveg, amely a kinyerni kívánt karaktereket tartalmazza.

A kezdés a kinyerni kívánt szöveg első karakterének pozíciója a szövegen belül.

A szám a szövegrész karaktereinek számát jelöli.

#### Példa

A =KÖZÉP("office";2;2) képlet az ff értéket adja vissza.

## KÖZÉP2

Eredményül egy kétbájtos karakterkészlettel írt szöveg egy darabját adja vissza. A kezdőpozíciót, illetve a karakterek számát a paraméterek határozzák meg.

Ez a funkció a LibreOffice 4.2 óta érhető el.

#### Szintaxis

KÖZÉP2("szöveg"; kezdés; bájtok_száma)

A szöveg olyan szöveg, amely a kinyerni kívánt karaktereket tartalmazza.

A kezdés a kinyerni kívánt szöveg első karakterének pozíciója a szövegen belül.

A bájtok_száma megadja bájtokban a karakterek számát, amennyit a KÖZÉP2 visszaad.

#### Példa

=MIDB("中国";1;0) returns "" (0 bytes is always an empty string).

=MIDB("中国";1;1) returns " " (1 byte is only half a DBCS character and therefore the result is a space character).

=MIDB("中国";1;2) returns "中" (2 bytes constitute one complete DBCS character).

=MIDB("中国";1;3) returns "中 " (3 bytes constitute one and a half DBCS character; the last byte results in a space character).

=MIDB("中国";1;4) returns "中国" (4 bytes constitute two complete DBCS characters).

=MIDB("中国";2;1) returns " " (byte position 2 is not at the beginning of a character in a DBCS string; 1 space character is returned).

=MIDB("中国";2;2) returns " " (byte position 2 points to the last half of the first character in the DBCS string; the 2 bytes asked for therefore constitutes the last half of the first character and the first half of the second character in the string; 2 space characters are therefore returned).

=MIDB("中国";2;3) returns " 国" (byte position 2 is not at the beginning of a character in a DBCS string; a space character is returned for byte position 2).

=MIDB("中国";3;1) returns " " (byte position 3 is at the beginning of a character in a DBCS string, but 1 byte is only half a DBCS character and a space character is therefore returned instead).

=MIDB("中国";3;2) returns "国" (byte position 3 is at the beginning of a character in a DBCS string, and 2 bytes constitute one DBCS character).

=MIDB("office";2;3) returns "ffi" (byte position 2 is at the beginning of a character in a non-DBCS string, and 3 bytes of a non-DBCS string constitute 3 characters).

## NAGYBETŰS

A szövegmezőben kijelölt szöveget nagybetűssé alakítja.

#### Szintaxis

NAGYBETŰS("szöveg")

A szöveg a nagybetűssé konvertálandó kisbetűk sorozata.

#### Példa

Az =NAGYBETŰS("Jó reggelt") eredményül a JÓ REGGELT karakterláncot adja.

## ÖSSZEFŰZ

Egyesíti a szöveg karakterláncait egyetlen karakterlánccá.

#### Szintaxis

ÖSSZEFŰZ(String 1 [; String 2 [; … [; String 255]]])

String 1[; String 2][; … ;[String 255]] are strings or references to cells containing strings.

#### Példa

Az =ÖSSZEFŰZ("Jó ";"reggelt, ";"Kovács ";"Úr!") eredményül a „Jó reggelt, Kovács Úr!” értéket adja.

## SOKSZOR

A megadott számszor ismétel egy karaktersorozatot.

#### Szintaxis

SOKSZOR("szöveg"; szám)

A szöveg az ismétlendő szöveg.

A szám az ismétlések száma.

#### Példa

A =SOKSZOR("Jó reggelt";2) eredménye Jó reggeltJó reggelt.

Refer to the REPT wiki page for more details about this function.

## SZÖVEG

Converts a value into text according to a given format.

#### Szintaxis

SZÖVEG(érték; formátum)

Value is the value (numerical or textual) to be converted.

A formátum a formátumot meghatározó szöveg. A tizedes-, illetve ezreselválasztókat a cellaformátum nyelvi beállításai szerint használja.

#### Példa

A =SZÖVEG(12,34567;"###,##") eredménye a 12,35 szöveg.

A =SZÖVEG(12,34567;"000,00") eredménye a 012,35 szöveg.

=TEXT("xyz";"=== @ ===") returns the text === xyz ===

See also Number format codes: custom format codes defined by the user.

## SZÖVEG.KERES

Returns the position of a text segment within a character string. You can set the start of the search as an option. The search text can be a number or any sequence of characters. The search is not case-sensitive. If the text is not found, returns error 519 (#VALUE).

The search supports wildcards or regular expressions. With regular expressions enabled, you can enter "all.*", for example to find the first location of "all" followed by any characters. If you want to search for a text that is also a regular expression, you must either precede every regular expression metacharacter or operator with a "\" character, or enclose the text into \Q...\E. You can switch the automatic evaluation of wildcards or regular expression on and off in LibreOffice - PreferencesTools - Options - LibreOffice Calc - Calculate.

When using functions where one or more arguments are search criteria strings that represents a regular expression, the first attempt is to convert the string criteria to numbers. For example, ".0" will convert to 0.0 and so on. If successful, the match will not be a regular expression match but a numeric match. However, when switching to a locale where the decimal separator is not the dot makes the regular expression conversion work. To force the evaluation of the regular expression instead of a numeric expression, use some expression that can not be misread as numeric, such as ".[0]" or ".\0" or "(?i).0".

#### Szintaxis

SZÖVEG.KERES("keresendő_szöveg"; "szöveg" [; pozíció])

A keresendő_szöveg a keresendő szöveg.

A szöveg a szöveg, amelyen belül a keresés végrehajtásra kerül.

A pozíció (opcionális) a keresés kiindulási helyét jelölő szövegpozíció.

#### Példa

A =SZÖVEG.KERES(54;998877665544) eredménye 10.

## SZÖVEG.TALÁL

Returns the position of a string of text within another string.You can also define where to begin the search. The search term can be a number or any string of characters. The search is case-sensitive.

#### Szintaxis

SZÖVEG.TALÁL("keresendő_szöveg"; "szöveg" [; pozíció])

A keresendő_szöveg a keresendő szöveg.

A szöveg az a szöveg, amelyen belül a keresés végrehajtásra kerül.

A pozíció (opcionális) a keresés kiindulási helyét jelölő szövegpozíció.

#### Példa

A =SZÖVEG.TALÁL(76;998877665544) függvény a 6 értéket adja vissza.

## T

A függvény az argumentumként megadott szöveget adja vissza, vagy üres szöveget ad vissza, ha az argumentum nem szöveg.

#### Szintaxis

T(érték)

Ha az érték karakterlánc vagy karakterláncra mutató hivatkozás, akkor a T a karakterláncot adja vissza, ellenkező esetben üres karakterláncot ad vissza.

#### Példa

A =T(12345) üres karakterláncot adja vissza.

A =T("12345") eredménye az 12345 karakterlánc.

## TISZTÍT

Az összes nem nyomtatható karaktert törli a karakterláncból.

#### Szintaxis

TISZTÍT("szöveg")

A szöveg az a szöveg, amelyből el kíván távolítani minden nem nyomtatható karaktert.

#### Példa

=LEN(CLEAN(CHAR(7) & "LibreOffice Calc" & CHAR(8))) returns 16, showing that the CLEAN function removes the non-printable Unicode U+0007 ("BEL") and U+0008 ("BS") characters at the beginning and end of the string argument. CLEAN does not remove spaces.

## TIZEDES

Converts text that represents a number in a numeral system with the given base radix to a positive integer. The radix must be in the range 2 to 36. Spaces and tabs are ignored. The Text field is not case-sensitive.

If the radix is 16, a leading x or X or 0x or 0X, and an appended h or H, are disregarded. If the radix is 2, an appended b or B is disregarded. Other characters that do not belong to the numeral system generate an error.

#### Szintaxis

TIZEDES("szöveg"; számrendszer)

Text is the text to be converted.

Radix indicates the base of the numeral system. It may be any positive integer between 2 and 36.

#### Példa

Az =TIZEDES("17";10) eredménye 17.

Az =TIZEDES("FACE";16) eredménye 64206.

Az =TIZEDES("0101";2) eredménye 5.

#### Lásd még

ALAP

## TNÉV

Nagybetűsre változtatja egy szöveg minden szavának első betűjét.

#### Szintaxis

TNÉV("szöveg")

A szöveg a konvertálandó szöveg.

#### Példa

=PROPER("the document foundation") returns The Document Foundation.

## UNICODE

A karakterlánc első Unicode karakterének numerikus kódját adja vissza.

#### Szintaxis

UNICODE("Szöveg")

#### Példa

A =UNICODE("©") a copyright karakter Unicode kódját, a 169-et adja eredményül.

Lásd még az UNIKARAKTER() függvényt.

## UNIKARAKTER

Numerikus kód Unicode karakterré vagy betűvé konvertálása.

#### Szintaxis

UNIKARAKTER(szám)

#### Példa

Az =UNIKARAKTER(169) a copyright karaktert © adja eredményül.

Lásd még az UNICODE() függvényt.

Kapcsolódó témakörök

Függvények kategória szerint