Tartalom
Index 🔎︎

# Munkafüzetfüggvények

Ez a szakasz tartalmazza a munkafüzet-kezelő függvények példával szemléltetett leírását.

Ennek a parancsnak az eléréséhez...

Válassza a Beszúrás - Függvény - Kategória: Munkafüzet lehetőséget.

## HIBA.TÍPUS

Visszaad egy konkrét hibatípust képviselő számot, vagy a #HIÁNYZIK hibaértéket, ha nincs hiba.

## ADDRESS

Egy cella címét (hivatkozását) adja eredményül szövegként, a meghatározott sor és oszlop száma szerint. Meghatározhatja, hogy a címzés abszolút címzésként (például: $A$1), relatív címzésként (például: A1) vagy esetleg a kettő ötvözeteként (A$1 vagy $A1) kerül értelmezésre. Ezen kívül megadhatja a munkalap nevét is.

Kompatibilitási okból a CÍM és INDIREKT függvények támogatnak egy opcionális paramétert, amellyel megadható hogy az R1C1 (S1O1) jelölés használandó-e a megszokott A1 stílus helyett.

A CÍM esetén a paraméter a negyedik paraméterként kerül megadásra, eltolva az opcionális munkalapnév paramétert az ötödik pozícióra.

Az INDIREKT esetén a paraméter második paraméterként kerül felhasználásra.

Mindkét függvény esetén az argumentum 0 értéke az R1C1 jelölés használatát jelenti. Ha az argumentum nincs megadva, vagy értéke nem nulla, akkor az A1 jelölés kerül felhasználásra.

Az R1C1 jelölés esetén a CÍM a cím karakterláncokat a munkalapnév-elválasztóként felkiáltójelet (!) használva adja vissza, az INDIREKT pedig felkiáltójeleket vár munkalapnév-elválasztóként. Mindkét függvény továbbra is a pont (.) munkalapnév-elválasztót használja az A1 jelölés esetén.

When opening documents from ODF 1.0/1.1 format, the ADDRESS functions that show a sheet name as the fourth parameter will shift that sheet name to become the fifth parameter. A new fourth parameter with the value 1 will be inserted.

A dokumentum ODF 1.0/1.1 formátumba mentésekor a CÍM függvények negyedik paramétere, ha van, eltávolításra kerül.

Ne mentse a táblázatot a régi ODF 1.0/1.1 formátumba, ha a CÍM függvény új negyedik paraméterét 0 értékkel használja.

Az INDIREKT függvény az ODF 1.0/1.1 formátumra átalakítás nélkül kerül mentésre. Ha a második paraméter jelen volt, a Calc régebbi verziója hibát ad vissza arra a függvényre.

#### Szintaxis

ADDRESS(Row; Column [; Abs [; A1 [; "Sheet"]]])

A sor a cellahivatkozás sorszámát jelöli.

Az oszlop a cellahivatkozás oszlopszámát (nem betűjelét) jelöli.

Az absz. meghatározza a hivatkozás típusát:

1: abszolút ($A$1)

2: a sorhivatkozás abszolút, az oszlophivatkozás relatív (A$1)

3: sor (relatív); oszlop (abszolút) ($A1)

4: relatív (A1)

A1 (opcionális) – ha 0, akkor az R1C1 jelölés érvényes. Ha a paraméter hiányzik, vagy nem 0, akkor az A1 jelölés érvényes.

A munkalap megadja a munkalap nevét. A nevet idézőjelek közé kell tenni.

### Példa:

A =CÍM(1;1;2;;"Munkalap2") a következőt adja eredményül: Munkalap2.A$1.

If the formula above is in cell B2 of current sheet, and the cell A1 in sheet 2 contains the value -6, you can refer indirectly to the referenced cell using a function in B2 by entering =ABS(INDIRECT(B2)). The result is the absolute value of the cell reference specified in B2, which in this case is 6.

## DDE

Egy DDE-alapú hivatkozás eredményét adja vissza. Ha a csatolt tartomány, illetve szakasz tartalma módosul, akkor az eredményül kapott érték maga is módosul. Ilyenkor újra kell töltenie a munkafüzetet, vagy a Szerkesztés - Hivatkozások menüparancsot kell választania a frissített hivatkozások megjelenítéséhez. A keresztplatformos hivatkozások (például Windows-gépen futó LibreOffice telepítésből Linux-gépen létrehozott dokumentumra) nem megengedettek.

#### Szintaxis

DDE("Server"; "File"; "Range" [; Mode])

Server is the name of a server application. LibreOffice applications have the server name "soffice".

A fájl elérési utat is tartalmazó teljes fájlnév.

A tartomány a kiértékelni kívánt adatokat tartalmazó terület.

A mód opcionális paraméter, amely szabályozza, hogy a DDE-kiszolgáló milyen módon konvertálja az adatokat számokká.

Mód | Hatás
0 vagy hiányzik | Számformátum az „Alapértelmezett” cellastílusból
1 | Az adatokat mindig a sztenderd amerikai angol szerint értelmezi
2 | Az adatot szövegként kapja meg; nem alakítja át számokká

#### Példa

A =DDE("soffice";"c:\office\document\adatok1.ods";"Munkalap1.A1") beolvassa az adatok1.ods LibreOffice-munkafüzet Munkalap1 nevű munkalapjának A1 celláját.

A =DDE("soffice";"c:\office\document\motto.odt";"Nap idézete") eredményül egy – a képletet tartalmazó cellában található – idézetet ad. Először írjon be egy idézetet tartalmazó sort a motto.odt dokumentumba, majd határozza meg a sort a Nap idézete szakasz első soraként (az LibreOffice Writer Létrehozás - Szakasz parancsának segítségével). Ha az idézetet módosítja a LibreOffice Writer-dokumentumban (és a dokumentumot menti), akkor az idézet az összes olyan LibreOffice Calc-cellában frissítésre kerül, amelyben a DDE-hivatkozás szerepel.

## ELTOLÁS

Egy adott hivatkozási ponttól megadott számú sorral és oszloppal eltolt cella értékét adja eredményül.

This function is always recalculated whenever a recalculation occurs.

#### Szintaxis

OFFSET(Reference; Rows; Columns [; Height [; Width]])

A hivatkozás azon hivatkozás, amelytől kezdve a függvény az új hivatkozást keresi.

A sorok azon sorok száma, amellyel a hivatkozás felfelé (negatív érték) vagy lefelé korrigálásra kerül. A 0 használatával ugyanabban a sorban maradhat.

Az oszlopok (opcionális) azon oszlopok száma, amellyel a hivatkozás balra (negatív érték) vagy jobbra korrigálásra kerül. A 0 használatával ugyanabban az oszlopban maradhat.

A magasság (opcionális) az új hivatkozáspozíción kezdődő terület függőleges magassága.

A szélesség (opcionális) az új hivatkozáspozíción kezdődő terület vízszintes szélessége.

A sorok és az oszlopok argumentumok nem mutathatnak nulla vagy negatív kezdetű sorra vagy oszlopra.

A magasság és a szélesség argumentumok nem mutathatnak nulla vagy negatív számú sorra vagy oszlopra.

A LibreOffice Calc függvényekben az opcionálisként jelölt paraméterek csak akkor hagyhatók el, ha nem következik paraméter. Például egy négy paramétert tartalmazó függvényben, ahol az utolsó két paraméter opcionálisként van jelölve, elhagyhatja a 4. paramétert vagy a 3. és 4. paramétert, de a 3. paramétert önmagában nem hagyhatja ki.

#### Példa

Az =ELTOLÁS(A1;2;2) eredményül a C3 cellában található értéket adja (A1-től két oszloppal jobbra és két sorral lefelé). Ha a C3 cella a 100 értéket tartalmazza, akkor a függvény eredményül a 100 értéket adja vissza.

Az =ELTOLÁS(B2:C3;1;1) a B2:C3 hivatkozástól az 1 sorral lejjebb és 1 oszloppal jobbra levő hivatkozást (C3:D4) adja vissza.

Az =ELTOLÁS(B2:C3;-1;-1) a B2:C3 hivatkozástól az 1 sorral feljebb és 1 oszloppal balra levő hivatkozást (A1:B2) adja vissza.

Az =ELTOLÁS(B2:C3;0;0;3;4) a B2:C3 hivatkozásból a 3 sorra és 4 oszlopra átméretezett hivatkozást (B2:E4) adja vissza.

Az =ELTOLÁS(B2:C3;1;0;3;4) a B2:C3 hivatkozásból az 1 sorral lejjebb tolt és 3 sorra és 4 oszlopra átméretezett hivatkozást (B3:E5) adja vissza.

A =SZUM(ELTOLÁS(A1;2;2;5;6)) a C3 cellánál kezdődő, 5 sor magas, és 6 oszlop széles terület (terület=C3:H7) összegét határozza meg.

If Width or Height are given, the OFFSET function returns a cell range reference. If Reference is a single cell reference and both Width and Height are omitted, a single cell reference is returned.

## FKERES

Függőleges keresés hivatkozással a jobb oldali szomszédos cellákra. Ez a függvény azt vizsgálja, hogy egy adott érték szerepel-e egy tömb első oszlopában. A függvény ezt az értéket adja vissza az index nevű oszlop azonos sorában. Ha a rendezett paraméter nincs megadva, IGAZ értékre, illetve 1-re van állítva, akkor a függvény úgy veszi, hogy az adatok növekvő sorrendben vannak. Ebben az esetben, ha nem található pontosan a keresési feltétel, akkor a keresési feltételnél kisebb utolsó érték lesz visszaadva. Ha a rendezett paraméter HAMIS vagy nulla, akkor pontos találatra van szükség, ellenkező esetben a Hiba: Érték nem érhető el hiba lesz az eredmény. A nulla érték mellett nem szükséges növekvő sorrendbe rendezni az adatokat.

The search supports wildcards or regular expressions. With regular expressions enabled, you can enter "all.*", for example to find the first location of "all" followed by any characters. If you want to search for a text that is also a regular expression, you must either precede every character with a "\" character, or enclose the text into \Q...\E. You can switch the automatic evaluation of wildcards or regular expression on and off in LibreOffice - PreferencesTools - Options - LibreOffice Calc - Calculate.

When using functions where one or more arguments are search criteria strings that represents a regular expression, the first attempt is to convert the string criteria to numbers. For example, ".0" will convert to 0.0 and so on. If successful, the match will not be a regular expression match but a numeric match. However, when switching to a locale where the decimal separator is not the dot makes the regular expression conversion work. To force the evaluation of the regular expression instead of a numeric expression, use some expression that can not be misread as numeric, such as ".[0]" or ".\0" or "(?i).0".

#### Szintaxis

=VLOOKUP(Lookup; Array; Index [; SortedRangeLookup])

Lookup is the value of any type looked for in the first column of the array.

Array is the reference, which is to comprise at least as many columns as the number passed in Index argument.

Az index a visszakapni kívánt értéket tartalmazó oszlop száma a tömbben. Az első oszlop száma 1.

A rendezett tartománykikeresés egy opcionális paraméter, amely azt jelzi, hogy a tömb első oszlopa tartományhatárokat tartalmaz-e egyszerű értékek helyett. Ebben az üzemmódban a keresés azt az értéket adja vissza a sorban, amelynek első oszlopában az érték egyenlő vagy kisebb, mint a keresési feltétel. Például tartalmazhat olyan dátumokat, amikor valamilyen adóértéket megváltoztattak, és így az értékek egy olyan időszak kezdődátumát jelentik, amikor egy adott adóérték érvényben volt. Így egy olyan dátum keresése, amely nem szerepel az első tömb oszlopában, de néhány meglévő határdátum közé esik, az alacsonyabbat adná meg, lehetővé téve a keresett dátumig érvényes adatok megtalálását. Adja meg a HAMIS vagy nulla logikai értéket, ha az első oszlop nem tartományhatár-lista. Ha ez a paraméter IGAZ vagy nincs megadva, akkor a tömb első oszlopát növekvő sorrendbe kell rendezni. A rendezett oszlopok sokkal gyorsabban kereshetők, és a függvény mindig visszaad egy értéket, még akkor is, ha a keresett érték nem egyezett pontosan, ha az nagyobb, mint a rendezett lista legalacsonyabb értéke. A rendezetlen listákban a keresési értéknek pontosan meg kell egyeznie. Ellenkező esetben a függvény a #HIÁNYZIK értéket adja vissza a következő üzenettel: Hiba: Érték nem érhető el.

Üres cellák kezelése

#### Példa

A menün található egyik étel számát meg kívánja adni az A1 cellában úgy, hogy az étel neve – szövegként – azonnal megjelenjen a szomszédos (B1) cellában. A Szám-Név hozzárendelést a D1:E100 tömb tartalmazza. A D1 100-at tartalmaz, E1 a Zöldségleves nevet tartalmazza, és így tovább, mind a száz menütételre. A D oszlop számai növekvő sorrendben rendezettek, tehát az opcionális rendezett paramétert nem szükséges megadni.

Adja meg a B1-es cellába a következő képletet:

=FKERES(A1;D1:E100;2)

Amint az A1 cellában megadja a számot, a B1 megjeleníti a D1:E100 hivatkozás második oszlopából a vonatkozó szöveget. Ha nem létező számot ad meg, akkor a következő számhoz tartozó szöveg jelenik meg. Ennek megakadályozására a képlet utolsó paramétereként adja meg a HAMIS értéket. Ennek eredményeként egy nem létező szám beírásakor hibaüzenet jelenik meg.

## HIBA.TÍPUS

Egy másik cellában fellépő hibaértéknek megfelelő számot ad eredményül. Ezeknek a számoknak a segítségével hibaüzeneteket hozhat létre.

Hiba esetén a függvény egy logikai vagy numerikus értéket ad vissza.

Ha a hibát tartalmazó cellára kattint, akkor az Állapotsorban megjelenik a LibreOffice termékben előre meghatározott hibakód.

#### Szintaxis

HIBA.TÍPUS(hivatkozás)

A hivatkozás a hibát tartalmazó cella címzése.

#### Példa

Ha az A1 cella a Hiba:518 hibakódot jeleníti meg, a =HIBA.TÍPUS(A1) függvény az 518 értéket adja vissza.

#### Technikai információk

This function is not part of the Open Document Format for Office Applications (OpenDocument) Version 1.3. Part 4: Recalculated Formula (OpenFormula) Format standard. The name space is

ORG.OPENOFFICE.ERRORTYPE

## HIPERHIVATKOZÁS

Ha olyan cellára kattint, amely a HIPERHIVATKOZÁS függvényt tartalmazza, a hiperhivatkozás megnyílik.

If you use the optional CellValue parameter, the formula locates the URL, and then displays the text or number.

Ha billentyűzetről akar megnyitni egy hiperhivatkozást tartalmazó cellát, jelölje ki a cellát, Szerkesztés módba történő váltáshoz nyomja meg az F2 billentyűt, vigye a kurzort a hiperhivatkozás elé, nyomja meg a Shift+F10 billentyűkombinációt, majd válassza a Hiperhivatkozás megnyitása menüparancsot.

#### Szintaxis

HYPERLINK("URL" [; CellValue])

URL specifies the link target. The optional CellValue parameter is the text or a number that is displayed in the cell and will be returned as the result. If the CellValue parameter is not specified, the URL is displayed in the cell text and will be returned as the result.

Üres cellákra és mátrixelemekre a 0 számot adja vissza.

#### Példa

=HYPERLINK("http://www.example.org") displays the text "http://www.example.org" in the cell and executes the hyperlink http://www.example.org when clicked.

=HYPERLINK("http://www.example.org";"Click here") displays the text "Click here" in the cell and executes the hyperlink http://www.example.org when clicked.

=HYPERLINK("http://www.example.org";12345) displays the number 12345 and executes the hyperlink http://www.example.org when clicked.

=HYPERLINK($B4) where cell B4 contains http://www.example.org. The function adds http://www.example.org to the URL of the hyperlink cell and returns the same text which is used as formula result.

=HYPERLINK("http://www.";"Click ") & "example.org" displays the text Click example.org in the cell and executes the hyperlink http://www.example.org when clicked.

=HYPERLINK("#Sheet1.A1";"Go to top") displays the text Go to top and jumps to cell Sheet1.A1 in this document.

=HYPERLINK("file:///C:/writer.odt#Specification";"Go to Writer bookmark") displays the text "Go to Writer bookmark", loads the specified text document and jumps to bookmark "Specification".

=HYPERLINK("file:///C:/Documents/";"Open Documents folder") displays the text "Open Documents folder" and shows the folder contents using the standard file manager in your operating system.

## HOL.VAN

Kiszámítja a megadott értékkel egyező tömb egy elemének relatív helyzetét. A függvény számként adja vissza a Keresési tömb segítségével megtalált érték helyzetét.

#### Szintaxis

HOL.VAN(keresés; keresési_tömb [; típus])

Search is the value which is to be searched for in the single-row or single-column array.

A keresési_tömb a keresés helyét megadó hivatkozás. A keresési tömb állhat egyetlen sorból vagy oszlopból, illetve lehet egy sor vagy oszlop egy része.

A típus az 1, 0, illetve -1 értékek valamelyikét veheti fel. Ha a típus = 1, illetve a választható paraméter nincs megadva, akkor a függvény feltételezi, hogy a keresési tömb első oszlopa növekvő sorrendben rendezett. Ha a típus = -1, akkor a függvény feltételezi, hogy az oszlop csökkenő sorrendben rendezett. Ez megegyezik a Microsoft Excel hasonló funkciójával.

Ha a típus = 0, akkor a függvény kizárólag a pontos egyezéseket találja meg. Ha a keresési feltétel több találatot eredményez, akkor a függvény az első találatot adja eredményül. Csak a típus = 0 esetén kereshet reguláris kifejezésekre (ha engedélyezett a számítás beállításaiban) vagy helyettesítő karakterekre (ha engedélyezett a számítás beállításaiban).

If Type = 1 or the third parameter is missing, the index of the last value that is smaller or equal to the search criterion is returned. For Type = -1, the index of the last value that is larger or equal is returned.

The search supports wildcards or regular expressions. With regular expressions enabled, you can enter "all.*", for example to find the first location of "all" followed by any characters. If you want to search for a text that is also a regular expression, you must either precede every character with a "\" character, or enclose the text into \Q...\E. You can switch the automatic evaluation of wildcards or regular expression on and off in LibreOffice - PreferencesTools - Options - LibreOffice Calc - Calculate.

When using functions where one or more arguments are search criteria strings that represents a regular expression, the first attempt is to convert the string criteria to numbers. For example, ".0" will convert to 0.0 and so on. If successful, the match will not be a regular expression match but a numeric match. However, when switching to a locale where the decimal separator is not the dot makes the regular expression conversion work. To force the evaluation of the regular expression instead of a numeric expression, use some expression that can not be misread as numeric, such as ".[0]" or ".\0" or "(?i).0".

#### Példa

A =HOL.VAN(200;D1:D100) a D oszlop szerint rendezett D1:D100 területen belül keresi a 200 értéket. Amint a függvény eléri ezt az értéket, az értéket tartalmazó sor száma visszaadásra kerül. Ha az oszlop keresése során a függvény ennél nagyobb értéket talál, akkor az előző sor száma kerül visszaadásra.

## INDEX

Az INDEX egy altartományt ad vissza, amelyet sor- vagy oszlopszám, illetve egy opcionális tartományindex határoz meg. A kontextustól függően az INDEX hivatkozást vagy tartalmat ad vissza.

#### Szintaxis

INDEX(Reference [; Row [; Column [; Range]]])

A hivatkozás közvetlenül vagy tartománynév megadásával meghatározott cellahivatkozás. Ha a hivatkozás több tartományból áll, akkor a hivatkozást, illetve tartománynevet zárójelek között szükséges megadni.

A sor (opcionális) a hivatkozástartomány sorindexe, amelyre vonatkozóan egy értéket meg kíván kapni. Nulla érték esetén (nincs megadva sor) visszaad minden hivatkozott sort.

Az oszlop (opcionális) a hivatkozástartomány oszlopindexe, amelyre vonatkozóan egy értéket meg kíván kapni. Nulla érték esetén (nincs megadva oszlop) visszaad minden hivatkozott oszlopot.

A tartomány (opcionális) az altartomány indexelése, több tartományt tartalmazó hivatkozás esetén.

#### Példa

Az =INDEX(Árak;4;1) eredményül az Adatok - Tartomány definiálása párbeszédablakban Árak néven megadott adatbázis-tartomány 4. sorának 1. oszlopában található értéket adja vissza.

Az =INDEX(SumX;4;1) eredményül a Munkalap - Nevesített tartományok és kifejezések - Megadás párbeszédablakban a SumX néven megadott adatbázis-tartomány 4. sorának 1. oszlopában található értéket adja vissza.

Az =INDEX(A1:B6;1) az A1:B6 első sorára mutató hivatkozást adja vissza.

Az =INDEX(A1:B6;0;1) az A1:B6 első oszlopára mutató hivatkozást adja vissza.

Az =INDEX((multi);4;1) eredményül a Munkalap - Nevesített tartományok és kifejezések - Megadás párbeszédablakban a multi néven megadott adatbázis-tartomány 4. sorának 1. oszlopában található értéket adja vissza. A többszörös tartomány több téglalap alakú tartományból állhat, és mindegyik rendelkezhet 4. sorral és 1. oszloppal. Ha a többszörös tartomány második blokkját kívánja meghívni, akkor tartomány paraméterként adjon meg 2-t.

Az =INDEX(A1:B6;1;1) az A1:B6 tartomány bal felső értékét jelöli.

Az =INDEX((multi);0;0;2) a többszörös tartomány második tartományára mutató hivatkozást adja vissza.

## INDIREKT

Egy karaktersorozat által meghatározott hivatkozást adja vissza. Ezzel a függvénnyel a megfelelő karakterlánc területét is vissza lehet adni.

This function is always recalculated whenever a recalculation occurs.

Kompatibilitási okból a CÍM és INDIREKT függvények támogatnak egy opcionális paramétert, amellyel megadható hogy az R1C1 (S1O1) jelölés használandó-e a megszokott A1 stílus helyett.

A CÍM esetén a paraméter a negyedik paraméterként kerül megadásra, eltolva az opcionális munkalapnév paramétert az ötödik pozícióra.

Az INDIREKT esetén a paraméter második paraméterként kerül felhasználásra.

Mindkét függvény esetén az argumentum 0 értéke az R1C1 jelölés használatát jelenti. Ha az argumentum nincs megadva, vagy értéke nem nulla, akkor az A1 jelölés kerül felhasználásra.

Az R1C1 jelölés esetén a CÍM a cím karakterláncokat a munkalapnév-elválasztóként felkiáltójelet (!) használva adja vissza, az INDIREKT pedig felkiáltójeleket vár munkalapnév-elválasztóként. Mindkét függvény továbbra is a pont (.) munkalapnév-elválasztót használja az A1 jelölés esetén.

When opening documents from ODF 1.0/1.1 format, the ADDRESS functions that show a sheet name as the fourth parameter will shift that sheet name to become the fifth parameter. A new fourth parameter with the value 1 will be inserted.

A dokumentum ODF 1.0/1.1 formátumba mentésekor a CÍM függvények negyedik paramétere, ha van, eltávolításra kerül.

Ne mentse a táblázatot a régi ODF 1.0/1.1 formátumba, ha a CÍM függvény új negyedik paraméterét 0 értékkel használja.

Az INDIREKT függvény az ODF 1.0/1.1 formátumra átalakítás nélkül kerül mentésre. Ha a második paraméter jelen volt, a Calc régebbi verziója hibát ad vissza arra a függvényre.

#### Szintaxis

INDIREKT(hivatkozás [; A1])

A hivatkozás cella- vagy területhivatkozás (szöveges formátumban), amelyre vonatkozóan a tartalmat meg kívánja kapni.

A1 (opcionális) – ha 0, akkor az R1C1 jelölés érvényes. Ha a paraméter hiányzik, vagy nem 0, akkor az A1 jelölés érvényes.

If you open an Excel spreadsheet that uses indirect addresses calculated from string functions, the sheet addresses will not be translated automatically. For example, the Excel address in INDIRECT("[filename]sheetname!"&B1) is not converted into the Calc address in INDIRECT("filename#sheetname."&B1).

#### Példa

Az =INDIREKT(A1) 100-zal egyenlő, ha az A1 cella a C108-as cellára való hivatkozást tartalmazza, és a C108 cella a 100 értéket tartalmazza.

A =SZUM(INDIREKT("A1:" & CÍM(1;3))) összegzi azon cellákat, amelyek az A1 cellától azon celláig terjedő területen találhatók, amely címét az 1. sor 3. oszlopában meghatározta. Tehát, az A1:C1 terület lesz összegezve.

## KERES

Egy egysoros vagy egyoszlopos cellatartományból származó cella tartalmát adja eredményül. Esetleg a hozzárendelt érték (azonos indexszel) egy másik sorban, illetve oszlopban kerül visszaadásra. Az FKERES és a VKERES függvénnyel ellentétben a keresési, illetve az eredményvektorok lehetnek eltérő helyeken, nem kell szomszédosnak lenniük. Ezen kívül a KUTAT keresési vektorját növekvő sorrendbe kell rendezni, ellenkező esetben a keresés nem jár használható eredménnyel.

Ha a KERES nem találja a keresési feltételt, a keresési vektor legnagyobb értékére illeszkedik, amely kisebb vagy egyenlő, mint a keresési feltétel.

The search supports wildcards or regular expressions. With regular expressions enabled, you can enter "all.*", for example to find the first location of "all" followed by any characters. If you want to search for a text that is also a regular expression, you must either precede every character with a "\" character, or enclose the text into \Q...\E. You can switch the automatic evaluation of wildcards or regular expression on and off in LibreOffice - PreferencesTools - Options - LibreOffice Calc - Calculate.

When using functions where one or more arguments are search criteria strings that represents a regular expression, the first attempt is to convert the string criteria to numbers. For example, ".0" will convert to 0.0 and so on. If successful, the match will not be a regular expression match but a numeric match. However, when switching to a locale where the decimal separator is not the dot makes the regular expression conversion work. To force the evaluation of the regular expression instead of a numeric expression, use some expression that can not be misread as numeric, such as ".[0]" or ".\0" or "(?i).0".

#### Szintaxis

LOOKUP(Lookup; SearchVector [; ResultVector])

Lookup is the value of any type to be looked for; entered either directly or as a reference.

A keresési_vektor az egyetlen sorból vagy egyetlen oszlopból álló terület, ahol keresni kell.

Az eredményvektor egy másik egyetlen sorból vagy egyetlen oszlopból álló tartomány, amelyből a függvény eredménye kiválasztásra kerül. Az eredmény az eredményvektor azon cellája, amely a keresési vektorban megtalált példánnyal azonos indexszel rendelkezik.

Üres cellák kezelése

#### Példa

A =KERES(A1;D1:D100;F1:F100) a D1:D100 tartomány vonatkozó cellájában keresi az A1 cellában megadott értéket. A megadott példányra a függvény megállapítja az indexet, például a tartomány 12. cellája. Ezt követően a 12. cella tartalma kerül visszaadásra a függvény eredményeként (az eredmény vektorban).

## KIMUTATÁSADATOT.VESZ

A KIMUTATÁSADATOT.VESZ függvény egy kimutatástáblából adja vissza az eredményt. Az érték címzése mező- és elemnevek használatával történik, így az érvényes marad akkor is, ha a kimutatástábla elrendezése megváltozik.

#### Szintaxis

Két különböző szintaxis használható:

GETPIVOTDATA(TargetField; pivot table[; Field 1; Item 1][; ... [Field 126; Item 126]])

vagy

KIMUTATÁSADATOT.VESZ(kimutatástábla; kényszerfeltételek)

A második szintaxis feltételezi, hogy pontosan két paraméter van megadva, és ezek közül az első egy cella- vagy cellatartomány-hivatkozás. Az első szintaxis van feltételezve minden más esetben. A Függvénytündér az első szintaxist jeleníti meg.

### Első szintaxis

A célmező egy karakterlánc, amely kijelöli a kimutatástábla adatmezőinek egyikét. A karakterlánc lehet egy forrásoszlop neve, vagy az adatcímke neve, ahogy az a táblázatban látható (például „Összeg - Eladások”).

A kimutatástábla egy hivatkozás egy cellára vagy cellatartományra, amely a kimutatástáblán belül van, vagy egy kimutatástáblát tartalmaz. Ha a cellatartomány több kimutatástáblát tartalmaz, akkor az utoljára létrehozott táblázat lesz használva.

Ha nincsenek megadva n. mező / n. elem párok, akkor az összeg lesz az eredmény. Egyébként mindegyik pár egy kényszerfeltételt ad hozzá, amelyet az eredménynek ki kell elégítenie. Az n. mező a kimutatástábla egyik mezőjének a neve. Az n. elem az abban a mezőben levő elem neve.

Ha a kimutatástábla csak egyetlen olyan eredményértéket tartalmaz, amely kielégíti a kényszerfeltételeket, vagy az összes illeszkedő értéket összegző részösszegeredményt, akkor az az eredmény lesz visszaadva. Ha nincs illeszkedő eredmény, vagy több van részösszeg nélkül, akkor hibajelzés lesz visszaadva. Ezek a feltételek a kimutatástáblában megtalálható eredményekre lesznek alkalmazva.

Ha a forrásadatok olyan bejegyzéseket tartalmaznak, amelyek a kimutatástábla beállításai miatt el vannak rejtve, akkor ezek nem lesznek figyelembe véve. A mező/elem párok sorrendje nem lényeges. A mező- és elemneveknél a kis- és nagybetűk nincsenek megkülönböztetve.

If no constraint for a filter is given, the field's selected value is implicitly used. If a constraint for a filter is given, it must match the field's selected value, or an error is returned. Filters are the fields at the top left of a pivot table, populated using the "Filters" area of the pivot table layout dialog. From each filter, an item (value) can be selected, which means only that item is included in the calculation.

A kimutatástáblából származó részösszegértékek csak akkor lesznek használva, ha azok az „auto” függvényt használják (kivéve ha a kényszerfeltételben van megadva, lásd alább a Második szintaxis részt).

### Második szintaxis

A kimutatástábla jelentése ugyanaz, mint az első szintaxisban.

A kényszerfeltételek egy szóközökkel elválasztott lista. Az elemeit aposztrófok közé lehet tenni. A teljes karakterláncot idézőjelek közé kell tenni, hacsak nem hivatkozik a karakterláncra egy másik cellából.

A bejegyzések egyike lehet az adatmező neve. Az adatmező neve kihagyható, ha a kimutatástábla csak egy adatmezőt tartalmaz, különben kötelező.

Minden más bejegyzés egy kényszerfeltételt határoz meg a Mező[Elem] (a [ és ] karakterrel) vagy csak az Elem formában, ha az elem neve egyedi a kimutatástáblában használt összes mező között.

A függvény neve a Mező[Elem;Függvény] formában adható meg, amely azt eredményezi, hogy a kényszerfeltétel csak azokra a részösszegekre illeszkedik, amelyek ezt a függvényt használják. A lehetséges függvénynevek: Összeg, Darab, Átlag, Maximum, Minimum, Szorzat, Darab (csak számok), Szórás (minta), SzórásP (sokaság), Variancia (minta) és VarianciaP (sokaság), a kis- és nagybetűk között nincs különbség.

## LAP

Returns the sheet number of either a reference or a string representing a sheet name. If you do not enter any parameters, the result is the sheet number of the spreadsheet containing the formula.

#### Szintaxis

LAP([hivatkozás])

A hivatkozás opcionális cella- vagy területhivatkozás, illetve munkalapnév-karakterlánc.

#### Példa

=SHEET(Sheet2.A1) returns 2 if Sheet2 is the second sheet in the spreadsheet document.

=SHEET("Sheet3") returns 3 if Sheet3 is the third sheet in the spreadsheet document.

## LAPOK

Megállapítja a hivatkozás munkalapjainak számát. Ha nem ad meg paramétereket, az aktuális dokumentum munkalapjainak számát adja vissza.

#### Szintaxis

LAPOK([hivatkozás])

A hivatkozás munkalap- vagy területhivatkozás. A paraméter megadása nem kötelező.

#### Példa

Az =LAPOK(Munkalap1.A1:Munkalap3.G12) függvény a 3 értéket adja vissza, ha a Munkalap1, Munkalap2 és Munkalap3 munkalapok a megadott sorrendben vannak.

## OSZLOP

Returns the column number of a cell reference. If the reference is a cell the column number of the cell is returned; if the parameter is a cell area, the corresponding column numbers are returned in a single-row array if the formula is entered as an array formula. If the COLUMN function with an area reference parameter is not used for an array formula, only the column number of the first cell within the area is determined.

#### Szintaxis

OSZLOP([hivatkozás])

A hivatkozás a cella-, illetve cellaterület-hivatkozás, amelyre vonatkozóan az első oszlop számát meg kívánja határozni.

Ha a hivatkozás értékének nem ad meg semmit, a képletet tartalmazó cella oszlopának számát adja vissza. A LibreOffice Calc a hivatkozást automatikusan az aktuális cellára állítja.

#### Példa

Az =OSZLOP(A1) képlet az 1 értéket adja vissza. Az A oszlop a táblázat első oszlopa.

Az =OSZLOP(C3:E3) képlet 3-mal egyenlő. A C oszlop a táblázat harmadik oszlopa.

Az =OSZLOP(D3:G10) eredményül 4-et ad, mivel a D oszlop a táblázat negyedik oszlopa, és az OSZLOP függvényt nem tömbképletként használta. (Ebben az esetben eredményül a függvény mindig a tömb első értékét adja vissza.)

Az {=OSZLOP(B2:B7)} és a =OSZLOP(B2:B7) eredményül egyaránt 2-t ad, mivel a hivatkozás csak a B oszlopot tartalmazza a táblázat második oszlopaként. Mivel az egyetlen oszlopból álló területek csak egy oszlopszámmal rendelkeznek, nem számít, hogy a képletet tömbképletként használja-e.

Az =OSZLOP() képlet a 3 értéket adja vissza, ha a képlet a C oszlopban lett megadva.

Az {=OSZLOP(Nyúl)} egy egyetlen sorból álló tömböt (3, 4) ad eredményül, ha a (C1:D3) terület neve „Nyúl”.

## OSZLOPOK

Az adott hivatkozásban szereplő oszlopok számát adja eredményül.

#### Szintaxis

OSZLOPOK(tömb)

A tömb az a cellatartomány-hivatkozás, amelyre vonatkozóan az oszlopok számát meg kívánja határozni. Az argumentum lehet egyetlen cella is.

#### Példa

Az =OSZLOPOK(B5) függvény az 1 értéket adja vissza, mert a cella csak egy oszlopot tartalmaz.

Az =OSZLOPOK(A1:C5) függvény értéke 3. A hivatkozás három oszlopot tartalmaz.

Az =OSZLOPOK(Nyúl) eredményül 2-t ad, ha a (C1:D3) tartomány neve Nyúl.

## ROW

Returns the row number of a cell reference. If the reference is a cell, it returns the row number of the cell. If the reference is a cell range, it returns the corresponding row numbers in a one-column Array if the formula is entered as an array formula. If the ROW function with a range reference is not used in an array formula, only the row number of the first range cell will be returned.

#### Szintaxis

SOR([hivatkozás])

A hivatkozás egy cella, egy terület vagy egy területnév.

Ha nem jelöl ki hivatkozást, a képletet tartalmazó cella sorának számát adja vissza. A LibreOffice Calc a hivatkozást automatikusan az aktuális cellára állítja.

#### Példa

A =SOR(B3) képlet a 3 értéket adja vissza, mert a hivatkozás a táblázat harmadik sorára hivatkozik.

A {=SOR(D5:D8)} képlet a (5, 6, 7, 8) egyoszlopos tömböt adja vissza, mert a megadott hivatkozás az 5 és 8 közötti sorokat tartalmazza.

A =SOR(D5:D8) képlet az 5 értéket adja vissza, mert a ROW függvényt nem tömbhivatkozásként használta, és csak a hivatkozás első sorának számát adja vissza.

A {=SOR(A1:E1)} és a =ROW(A1:E1) egyaránt 1-et ad vissza, mivel a hivatkozás csak az 1. sort tartalmazza a táblázat első soraként. (Mivel az egyetlen sorból álló területek csak egy sorszámmal rendelkeznek, nem számít, hogy a képletet tömbképletként használja-e.)

A =SOR() képlet a 3 értéket adja vissza, ha a képletet a 3. sorba írja be.

A {=SOR(Nyúl)} egy egyetlen sorból álló tömböt (1, 2, 3) ad eredményül, ha a (C1:D3) terület neve „Nyúl”.

## SOROK

Egy hivatkozás vagy tömb sorainak számát adja eredményül.

#### Szintaxis

SOROK(tömb)

A tömb az a hivatkozás vagy névvel ellátott terület, amelyre vonatkozóan a sorok számát meg kívánja határozni.

#### Példa

A =SOROK(B5) képlet az 1 értéket adja vissza, mert a cella csak egy oszlopot tartalmaz.

A =SOROK(A10:B12) képlet a 3 értéket adja vissza.

A =SOROK(Nyúl) eredményül 3-at ad, ha a (C1:D3) terület neve „Nyúl”.

## STYLE

Stílust alkalmaz a képletet tartalmazó cellára. Meghatározott idő elteltével egy másik stílus alkalmazható. Ez a függvény mindig 0 értéket ad vissza, így az érték megváltoztatása nélkül hozzáadhatja egy másik függvényhez. A CURRENT függvénnyel együtt az értéktől függően színt alkalmazhat egy cellára. Például: =...+STÍLUS(HA(CURRENT()>3; "piros"; "zöld")) a "piros" stílust alkalmazza a cellára, ha az érték nagyobb, mint 3, egyébként a "zöld" stílust alkalmazza. Mindkét cellaformátumot, a "pirosat" és a "zöldet" előzetesen definiálni kell.

#### Szintaxis

STYLE("Style" [; Time [; "Style2"]])

A stílus a cellához rendelt stílus neve. A stílusneveket idézőjelek között kell megadni.

Az idő (opcionális) másodpercekben megadott időtartomány. Ha a paraméter nincs megadva, akkor a stílus nem kerül módosításra egy adott idő elteltével.

A stílus_2 (opcionális) a cellához egy bizonyos idő elteltével hozzárendelésre kerülő stílus neve. Ha a paraméter nincs megadva, akkor a függvény az „Alapértelmezett” stílust használja.

A LibreOffice Calc függvényekben az opcionálisként jelölt paraméterek csak akkor hagyhatók el, ha nem következik paraméter. Például egy négy paramétert tartalmazó függvényben, ahol az utolsó két paraméter opcionálisként van jelölve, elhagyhatja a 4. paramétert vagy a 3. és 4. paramétert, de a 3. paramétert önmagában nem hagyhatja ki.

#### Példa

A =STYLE("Láthatatlan";60;"Alapértelmezett") a cellát átlátszó formátummal formázza a dokumentum újraszámítását, illetve betöltését követően 60 másodpercig, majd az Alapértelmezett formátum kerül a cellához hozzárendelésre. Mindkét cellaformátumot használat előtt meg kell határoznia.

Since STYLE() has a numeric return value of zero, this return value gets appended to a string. This can be avoided using T() as in the following example:

="Szöveg"&T(STYLE("Saját stílus"))

Egy másik példáért lásd még a CURRENT() leírását.

#### Technikai információk

This function is not part of the Open Document Format for Office Applications (OpenDocument) Version 1.3. Part 4: Recalculated Formula (OpenFormula) Format standard. The name space is

ORG.OPENOFFICE.STYLE

## TERÜLET

Azon tartományok számát adja eredményül, amelyek egy többszörös tartományba tartoznak. Egy tartomány összefüggő cellákból vagy egy magában álló cellából állhat.

A függvény egyetlen argumentumot vár. Ha több tartományt ad meg, akkor ezeket további zárójelek közé kell tenni. Több tartomány pontosvesszővel (;) elválasztva írható be, de ez automatikusan a tilde (~) operátorrá lesz alakítva. A tilde használatos tartományok összekapcsolására.

#### Szintaxis

TERÜLET(hivatkozás)

A Hivatkozás a cellához vagy cellatartományhoz tartozó hivatkozást jelöli.

#### Példa

Az =TERÜLET(A1:B3;F2;G1) függvény a 3 értéket adja vissza, mert ez három cellára és/vagy területre való hivatkozást tartalmaz. A bevitel után ez a =TERÜLET((A1:B3~F2~G1)) képletté konvertálódik.

Az =TERÜLET(Minden) eredményül 1-et ad akkor, ha megadott egy Minden nevű területet az Adatok - Tartomány definiálása párbeszédablakban.

## VÁLASZT

Egy 1-től 30-ig terjedő listából index használatával visszaad egy értéket.

#### Szintaxis

CHOOSE(Index; Value 1 [; Value 2 [; ... [; Value 30]]])

Az index 1–30 közötti érték vagy hivatkozás, amely meghatározza, hogy a lista melyik eleme kerül visszaadásra.

Value 1, Value 2, ..., Value 30 is the list of values entered as a reference to a cell or as individual values.

#### Példa

A =VÁLASZT(A1;B1;B2;B3;"Ma";"Tegnap";"Holnap") például a B2 cella tartalmát adja eredményül A1 = 2 esetén. A1 = 4 esetén a függvény a „Ma” szöveget adja eredményül.

## VKERES

A kijelölt terület alatti cellákhoz értéket és hivatkozást keres. A függvény ellenőrzi, hogy egy tömb első sora tartalmaz-e egy bizonyos értéket. A függvény ezután visszaadja a tömb egy sorának az index oszlopban megnevezett értékét ugyanabban az oszlopban.

The search supports wildcards or regular expressions. With regular expressions enabled, you can enter "all.*", for example to find the first location of "all" followed by any characters. If you want to search for a text that is also a regular expression, you must either precede every character with a "\" character, or enclose the text into \Q...\E. You can switch the automatic evaluation of wildcards or regular expression on and off in LibreOffice - PreferencesTools - Options - LibreOffice Calc - Calculate.

When using functions where one or more arguments are search criteria strings that represents a regular expression, the first attempt is to convert the string criteria to numbers. For example, ".0" will convert to 0.0 and so on. If successful, the match will not be a regular expression match but a numeric match. However, when switching to a locale where the decimal separator is not the dot makes the regular expression conversion work. To force the evaluation of the regular expression instead of a numeric expression, use some expression that can not be misread as numeric, such as ".[0]" or ".\0" or "(?i).0".

#### Szintaxis

HLOOKUP(Lookup; Array; Index [; SortedRangeLookup])

For an explanation on the parameters, see: VLOOKUP (columns and rows are exchanged)

Üres cellák kezelése

#### Példa

Suppose we have built a small database table occupying the cell range A1:DO4 and containing basic information about 118 chemical elements. The first column contains the row headings “Element”, “Symbol”, “Atomic Number”, and “Relative Atomic Mass”. Subsequent columns contain the relevant information for each of the elements, ordered left to right by atomic number. For example, cells B1:B4 contain “Hydrogen”, “H”, “1” and “1.008”, while cells DO1:DO4 contain “Oganesson”, “Og”, “118”, and “294”.

| A | B | C | D | ... | DO
--- | --- | --- | --- | --- | --- | ---
1 | Elem | Hidrogén | Hélium | Lítium | ... | Oganeszon
2 | Szimbólum | H | He | Li | ... | Og
3 | Rendszám | 1 | 2 | 3 | ... | 118
4 | Relatív atomtömeg | 1.008 | 4.0026 | 6.94 | ... | 294

=HLOOKUP("Lead"; $A$1:$DO$4; 2; 0) returns “Pb”, the symbol for lead.

=HLOOKUP("Gold"; $A$1:$DO$4; 3; 0) returns 79, the atomic number for gold.

=HLOOKUP("Carbon"; $A$1:$DO$4; 4; 0) returns 12.011, the relative atomic mass of carbon.

Kapcsolódó témakörök

Függvények kategória szerint