Функция StrConv [VBA]

Съдържание
Индекс 🔎︎

# Функция StrConv

Преобразува низ според зададен тип на преобразуването.

Тази константа, функция или обект се разрешава с оператора Option VBASupport 1, поставен преди изпълнимия програмен код в модула.

### Синтаксис:

StrConv(Text, Conversion, [ LCID ])

### Резултат:

String

### Параметри:

Text: произволен валиден израз със стойност низ.

Conversion: типът на преобразуването, което да се извърши, както е дефиниран в таблицата по-долу.

Преобразуване | Стойност | Описание
--- | --- | ---
vbUpperCase | 1 | Преобразува знаците от Text към горен регистър.
vbLowerCase | 2 | Преобразува знаците от Text към долен регистър.
vbProperCase | 3 | Преобразува първата буква от всяка дума в Text към горен регистър.
vbWide | 4 | Преобразува тесните знаци (с половин ширина) в Text към широки знаци (с пълна ширина).
vbNarrow | 8 | Преобразува широките знаци (с пълна ширина) в Text към тесни знаци (с половин ширина).
vbKatakana | 16 | Преобразува знаците от хирагана в Text към знаци от катакана.
vbHiragana | 32 | Преобразува знаците от катакана в Text към знаци от хирагана.
vbUnicode | 64 | Преобразува знаците от Text към знаци от Уникод, използвайки подразбираната кодова страница на системата.
vbFromUnicode | 128 | Преобразува знаците в Text от Уникод към подразбираната кодова страница на системата.

LCID Незадължителен. Идентификатор на локал във вид на десетично число. Ако този параметър е пропуснат, се подразбира системният идентификатор на локал. Вижте файла msi-encodinglist.txt за допустимите стойности на LCID.

### Пример:

    Option VBASupport 1
    Option Explicit
    Sub Test_StrConv
        Print StrConv("abc EFG hij", vbUpperCase) '= "ABC EFG HIJ"
        Print StrConv("abc EFG hij", vbLowerCase) ' =  "abc efg hij"
        Print StrConv("abc EFG hij", vbProperCase) ' = "Abc Efg Hij"

        REM Преобразува тесните (еднобайтови) знаци от низа в широки.
        Print StrConv("ABCDEVB¥ì¥¹¥¥å©", vbWide) ' = "ＡＢＣＤＥＶＢ￥ì￥¹￥￥å©"

        REM Преобразува широките (двубайтови) знаци от низа в тесни (еднобайтови).
        Print StrConv("ＡＢＣＤ＠＄％２３＇？ＥＧ", vbNarrow) ' = "ABCD@$%23'?EG"

        REM Преобразува знаците от хирагана в низа към знаци от катакана.
        Print StrConv("かたかな", vbKatakana) ' = "カタカナ"

        REM Преобразува знаците от катакана в низа към знаци от хирагана.
        Print StrConv("カタカナ", vbHiragana) '= "かたかな"

        REM  Подразбира се кодиране CP-1252, свързано с локал en-US, използван за компонентно тестване.
        Dim x() As Byte
        x = StrConv("ÉÏº£ÊÐABC", vbFromUnicode)
        Print UBound(x) ' 8 знака
        Print x(2) ' = 186
        Print StrConv(x, vbUnicode)' = "ÉÏº£ÊÐABC"
    End Sub

Теми, свързани с показаната

Функции и оператори само във VBA